DAFFY MK TWO
/DISPLAYS AA FILE FOR YOU
21/	HLT
4000/
RDOCT,	LAW 5777	/READ OCTAL TAPE
	DAC 10	/AUTO-INDEX
	LAC (2000
	DAC 6000	/STOP DISPLAY IF RUNNING
OCTLP,	LAM -5
	DAC CNT#
	DZM SAVE2
	LAC (1)
	DAC NUMB#
BEGIN1,	JMS CHARIN
	SAD (215)
	JMP BEGIN1
	SAD (12)
	JMP BEGIN1
	SAD (240)
	JMP BEGIN1
	AND (7)
	DAC SAVE1#
	LAC NUMB
	ISZ NUMB
	MUL
	3
	LACQ
	XOR (LRS)
	DAC .+2
	LAC SAVE1
	XX	/FOR SHIFT
	LACQ
	XOR SAVE2#
	DAC SAVE2
	ISZ CNT
	JMP BEGIN1
	LAC SAVE2
	DAC I 10
	JMP OCTLP
CHARIN,	0
	LAM -25
	DAC 7
	CLON
	RSA
	CLSF
	SKP
	JMP CHEXIT
	RSF
	JMP .-4
	RRB
	CLOF
	SNA
	JMP CHARIN+1
	JMP I CHARIN
CHEXIT,	RRB
	JMP SHOWIT
SHOWIT,	IDCF
	LAW 6000
	IDLA
	JMP 16000	/ENTER DDT
RDDEC,	LAW 5777	/READ DECIMAL TAPE
	DAC 10	/AUTO-INDEX
	LAC (2000
	DAC 6000	/STOP DISPLAY IF RUNNING
GO2,	JMS CHARIN	/GET CHARACTER
	JMS CHKDEC	/CHECK IF DECIMAL INTEGER OR -
	SKP	/DEC INTEGER OR -
	JMP GO2	/IGNORE
	DZM #WORD
	DZM #SIGN
	SMA
	JMP GO1
	CLC	/-SIGN
	DAC SIGN
	JMP GO3
GO1,	DAC #TEM1
	LAC WORD
	RCL
	RCL	/4X
	TAD WORD
	RCL	/10X
	TAD TEM1
	DAC WORD
GO3,	JMS CHARIN
	JMS CHKDEC
	JMP GO1	/DEC INTEGER
	LAC WORD	/TERMINATOR READ
	ISZ SIGN
	JMP .+3	/POSITIVE INTEGER
	CMA
	TAD (1	/NEGATE
	DAC I 10
	JMP GO2
CHKDEC,	0	/CHECKS IF DEC. INTEGER OR -
	AND (177	/IGNORE EIGHTH TRACK
	DAC TEM1
	CMA
	TAD (60
	CMA
	DAC #TEM2	/DECIMAL INTEGER
	SPA
	JMP NDEC	/NOT DECIMAL
	CMA
	TAD (12
	CMA
	SMA
	JMP NDEC	/NOT DECIMAL
	LAC TEM2	/DECIMAL INTEGER
	JMP I CHKDEC
NDEC,	LAC TEM1	/CHARACTER
	SAD (55		/SEE IF -
	JMP .+3
	ISZ CHKDEC	/NOT DEC INT OR -
	JMP I CHKDEC
	CLC
	JMP I CHKDEC	/EXIT WITH -ACC
PLOT,	LAC (306000	/NEW FRAME AND DF AT 6000
	JMS 36	/ENTER PLOD LOW CORE VERSION
	JMP 16000	/BACK TO DDT
START RDOCT

