STRIP
/STREAMLINED (PERIPHERAL) INTERCHANGE PROGRAM
/RJC 22.7.70
/USES FODDER,DTBTRN,NEW TELETYPE OUTPUT PACKAGE AND OCTAL PRINT SUB.
LISTY=26
TRANO=123	/FOR ENTRY TO DECTAPE DISPLAY
11000/	/RECONSTITUTE FIRM START WHEN STRIP LOADED
	LAC (HLT)	/PAUSE TO SET AC SWITCHES
	DAC 17603
	LAC (LAS)	/READ AC SWITCHES
	DAC 17626
BEGIN,	LAW PMESS	/PRINT "STRIP CR,LF"
	TSR
	DZM ALTSET#
	JMP RESTORE	/INITIALISE PROGRAM
GO,	CAF	/CLEAR ALL FLAGS
	LAC ALTSET	/CHECK SWOPPING SWITCH
	SNA
	JMP .+4
	LAC (2000)	/BIT 7 FOR STEED
	DAC SWITCH
	JMP STEED+7
	LAC (363676)
	TY3	/PRINT NEWLINE, >
	LAC (1)
	DAC #DBCNT	/SET NUMBER OF BLOCKS
/SECTION TO SEE WHICH OPERATION HAS BEEN REQUESTED
GOMORE,	JMS RDCHAR
	SAD (240)	/IGNORE LEADING SPACES
	JMP GOMORE
	SAD (202)	/CTRL B - ENTER BATCH MODE (PR)
	JMP SBATCH
	SAD (205)	/CTRL E - LOAD EDITOR
	JMP STEED
	SAD (230)	/CTRL X - LOAD PADDLE
	JMP PADDLE
	SAD (222)	/CTRL R - LOAD RDF
	JMP RDF
	SAD (203)	/CTRL C - LOAD DECTAPE COPY/COMPARE
	JMP COPCOM
	SAD (221)	/CTRL Q - LOAD DSP
	JMP DSP
	SAD (223)	/CTRL S - RELOAD STRIP
	JMP STRIP
	SAD (201)	/CTRL A - LOAD SADIE ASSEMBLER
	JMP SADIE
	SAD (204)	/CTRL D - LOAD DDT RUDI (WITHOUT TRACER)
	JMP DDT
	SAD (214)	/CTRL L - LOAD PLOTALOT
	JMP PLOTALOT
	SAD (206)	/CTRL F - LOAD PEDRO
	JMP PEDRO
	SAD (314)	/L - LIST DIRECTORY
	JMP SLIST
	SAD (311)	/I - INITIALISE DECTAPE
	JMP SINIT
	SAD (304)	/D - DELETE FILE
	JMP SDELET
	SAD (322)	/R - RENAME FILE
	JMP SNEWNM
	SAD (327)	/W - WRITE NEW FILE FROM PAPER TAPE
	JMP SADDFL
	SAD (320)	/P - PUNCH FILE
	JMP SPUNCH
	SAD (303)	/C - COPY FILE
	JMP SCVER
	SAD (326)	/V - VERIFY FILES
	JMP VERIFY
	SAD (325)	/U - UPDATE - COPY AND OVERWRITE
	JMP UPDATE
	SAD (321)	/Q - QUERY BIT MAPS
	JMP QUERY
	SAD (324)	/T - TYPE FILE
	JMP STYPE
	SAD (302)	/B - FREE BLOCK COUNT
	JMP BLC
	SAD (323)	/S - AWAIT DECTAPE DISPLAY COMMAND
	JMP 22
	SAD (242)	/" - INPUT COMMENT
	JMP COMMENT
	SAD (215)	/CR - IGNORE
	JMP BEGIN+3
	SAD (212)	/LF - IGNORE
	JMP BEGIN+3
GOERR,	LAW ERR7	/ILLEGAL OPERATION CODE
	TSR
	JMP BEGIN+3
/******
/******
RESTORE,	LAC (JMS SRTAPE)
	DAC SLMORE+3
	LAC (JMS PBLANK)
	DAC SFERR-5
	DAC SIFEND+6
	LAC (LAC ODELET)
	DAC SFENDX
	LAC (JMS OPP)
	DAC SLOVER-5
	LAC (JMS BONNUM)
	DAC SFWRTE+1
	LAC (JMP SFEXIT)
	DAC SFWRTE+11
	LAC (LAC NMCOPY)
	DAC NSWOP+1
	LAC (JMS NMREAD)
	DAC SFOPEN+1
	LAC (JMS NPRINT)
	DAC SFESTA+2	/RESTORE ERROR FOR FILE NAME IN USE
	LAW SEVPAR	/ROUTINE TO SET EVEN PARITY
	DAC SCHOUT#	/CALLED BY JMS I SCHOUT
	LAW 12
	DAC SLFEED#
	LAW SUNPAK	/IOPS ASCII UNPACKING HANDLER
	DAC SGETCH	/CALLED BY JMS I SGETCH
	DZM IDELET#
	DZM ODELET#
	DZM PINDIC#	/PUNCH SWITCH FOR UPDATE
	DZM DLIST#	/LISTING SWITCH FOR UPDATE
	DZM DQUERY#	/QUERY SWITCH FOR UPDATE
	LAC (2)
	DAC SMODE#	/IOPS ASCII MODE
	LAC (TLS)
	DAC OTY+1
	JMP GO
/******
/******
OTY,	0	/USED BY NEW TELETYPE OUTPUT PACKAGE	
	TLS
	TSF
	JMP .-1
	JMP I OTY
/******
/******
HANDLE,	0	/ROUTINE TO EXECUTE L,I,B,Q COMMANDS
		/ON UNITS SELECTED
	JMS RDCHAR
	SAD (215)
	JMP .+11
	JMS UNITS	/GET UNITS REQUIRED
	LAC I 17
	SPA
	JMP .+6
	DAC NB-1
	DAC NBLOCK-1
	XCT I HANDLE
	JMP .-6
	XCT I HANDLE
	ISZ HANDLE
	JMP I HANDLE
SLIST,	JMS HANDLE
	JMS DRPRNT	/LIST DIRECTORY
	JMP BEGIN+3
SINIT,	JMS HANDLE
	JMS SETAPE	/INITIALISES DECTAPE
	JMP BEGIN+3
SDELET,	JMS FILDEL	/DELETES A FILE
	JMP BEGIN+3
SNEWNM,	JMS NEWNAM	/RENAMES A FILE
	JMP BEGIN+3
COMMENT,	JMS RDCHAR
	SAD (242)	/" - END OF COMMENT
	JMP BEGIN+3
	JMP COMMENT
BLC,	JMS HANDLE
	JMS BLC1	/FREE BLOCK COUNT
	JMP BEGIN+3
BLC1,	0
	JMS DBREAD	/GET DIRECTORY BIT MAP
	LAW FIOBUF-1
	DAC FADDR
	LAW DBMAP-1
	DAC FSAVER
	LAM -37
	JMS DFTRAN
	TCR	/NEWLINE
	JMS BONNUM	/COUNT FREE BLOCKS
	JMS OPS	/PRINT IN OCTAL
	LAW ENDMES	/"X FREE BLOCKS"
	TSR
	LAC NB-1
	TAD (042460)	/DTX
	TY3
	JMP I BLC1
SBATCH,	JMS CPRINT	/CTRL B
	LAC (JMS PTIN)	/SET UP READER ROUTINE
	DAC RDCHAR+1
	DAC RDCHR5
	JMP GOMORE	/SERVICE PAPER TAPE READER
PTIN,	0	/PAPER TAPE READER HANDLER FOR BATCH MODE
	RSA	/READER ALPHA
	KSF	/SEE IF KEYBOARD INTERRUPT
	SKP
	JMP PTIN1	/SEE IF CTRL P
	RSF	/READER?
	JMP .-4
	RRB
	SNA
	JMP PTIN+1	/IGNORE RUNOUT
	AND (177)	/FORCE BIT 8
	XOR (200)
	JMP I PTIN
PTIN1,	KRB	/READ KEYBOARD BUFFER
	SAD (220)	/CTRL P
	JMP RDCHR1
	JMP PTIN+2
STYPE,	JMS RDCHAR
	LAW TTLIST	/TELEPRINTER HANDLER
	DAC SCHOUT
	LAC (2)
	DAC SMODE	/IOPS ASCII MODE
	LAC (NOP)
	DAC SIFEND+6
	DAC SLOVER-5
	LAC (JMS TTSTAR)	/TELEPRINTER INITIALISE ROUTINE
	DAC SFERR-5
	JMP SPUNCH+1	/USE P ROUTINE
QUERY,	JMS HANDLE
	JMS TCHECK	/VERIFY BIT MAPS
	JMP BEGIN+3
UPDATE,	LAC (JMP VNOTE)
	DAC SFESTA+2
	JMP SCVER
VNOTE,	LAC SAVE	/INDEX NUMBER
	DAC OSAVE#
	ISZ ODELET
	JMP SFESTA+1
SCVER,	DZM #CANDV
	DZM NMBUFF
	JMS RDCHAR
SCOPY,	LAC (JMP SCOPY1)
	DAC SFWRTE+11	/FOR EOT CONDITION
	JMS HINOUT	/GET INPUT AND OUTPUT HANDLERS
	SAD (215)	/CARRIAGE-RETURN
	SKP
	JMP .+5
	LAC (NOP)
	DAC SFOPEN+1
	LAC NSWOP+7
	DAC NSWOP+1
	LAC HIN	/INPUT HANDLER
	DAC NB-1
	LAC (JMP SCVER2)
	DAC SFENDX
	LAC (SKP)
	DAC SFERR-5	/CUT OUT PUNCH
	JMS SFOPEN
	LAC SAVE
	DAC ISAVE#
	LAC NB
	DAC #NBSAV
	DAC #VERIN
	LAC HOUT	/OUTPUT HANDLER
	DAC NBLOCK-1
	DAC NB-1
	JMS NSWOP	/GET NAME OF OUTPUT FILE
	LAW .+3
	DAC SFEST	/FIDDLE INTERNAL JUMP TO SFEST
	JMP SFEST+2	/INTERNAL JUMP TO SFEST
/HERE IF FILES OPENED AND ESTABLISHED. COMMENCE COPY
	LAC HIN
	DAC NB-1
	LAC BLSAV
	DAC NBLOCK
	DAC #VEROUT
	LAC NBSAV
SCOPY2,	DAC NB
	JMS TREAD	/READ BLOCK OF INPUT FILE
	KSF
	SKP
	JMS RDCHAR
	LAC FIOBUF+377
	SAD (-0)	/SEE IF END OF FILE
	JMP SCOPY1
	DAC NBSAV
	LAC NBLOCK
	DAC FIOBUF+377
	JMS SFWRTE	/WRITE BLOCK
	LAC FIOBUF+377	/SAVE BLOCK NUMBER
	DAC NBLOCK
	JMS DIRGET	/DETERMINE NEXT READ DIRECTION
	LAC NBSAV	/NEXT BLOCK (DATA LINK)
	ADD NB	/LAST BLOCK
	DAC DIRSAV
	LAC NBSAV
	JMP SCOPY2
SCOPY1,	LAC HOUT
	DAC NBLOCK-1
	DAC NB-1
	LAC DIRN
	DAC DIRSAV
	JMP SFEXIT+10	/CLOSES FILE
SCVER2,	LAC ODELET
	SZA
	JMS OVERWR	/OVERWRITE
	LAC IDELET
	SZA
	JMS INDELT	/DELETE INPUT FILE
	LAC PINDIC
	SZA
	JMS PUNCHN	/PUNCH UPDATED FILE
	LAC DQUERY
	SZA
	JMS TCHECK	/QUERY BIT MAPS
	LAC DLIST
	SZA
	JMS DRPRNT	/LIST DIRECTORY
	ISZ CANDV
	JMP RESTORE
	LAC VERIN
	DAC SCNT1
	LAC VEROUT
	DAC SCNT2
	DZM DINSAV
	DZM DOUTSAV
	JMP VERIF2
/******
/******
PUNCHN,	0	/PUNCHES UPDATED FILE
	LAC HOUT
	DAC NB-1
	LAC (JMS PBLANK)
	DAC SFERR-5
	LAW .+4	/FOR INTERNAL SUBROUTINE ENTRY
	DAC SFOPEN
	LAC VEROUT	/START BLOCK OF FILE
	JMP SFOPEN+6
	JMS SIBUFF
	JMP I PUNCHN
/******
/******
UNITS,	0	/GETS UNITS FOR L,I,B,Q
	LAW UBUFF-1
	DAC 17
	LAM -2
	DAC CNT
UNITS1,	JMS HANNO
	DAC FADDR
	LAC NB-1
	DAC I 17
	ISZ CNT
	SKP
	JMP .+5
	LAC FADDR
	SAD (215)
	SKP
	JMP UNITS1
	LAM
	DAC I 17
	LAW UBUFF-1
	DAC 17
	JMP I UNITS
/******
/******
NSWOP,	0
	LAC NMCOPY
	DAC NMBUFF
	LAC NMCOPY+1
	DAC NMBUFF+1
	LAC NMCOPY+2
	DAC NMBUFF+2
	JMP I NSWOP
/******
/******
OVERWR,	0	/DELETES OUTPUT FILE IF NECESSARY IN UPDATING
	LAC HOUT
	DAC NB-1
	DAC NBLOCK-1	/OUTPUT TRANSPORT
	LAC OSAVE
	DAC SAVE
	JMS DBREAD	/LOAD DIRECTORY
	JMS DELET4	/ERASE FILE
	JMP I OVERWR
/******
/******
INDELT,	0	/DELETES INPUT FILE IF REQUESTED
	LAC HIN
	DAC NB-1
	DAC NBLOCK-1
	LAC ISAVE
	DAC SAVE
	JMS DBREAD
	JMS DELET4
	JMP I INDELT
/******
/******
HINOUT,	0	/ACCEPTS INPUT AND OUTPUT UNIT NUMBERS
	JMS RDDEV
	SAD (DT)
	SKP
	JMP H1
	JMS RDCHAR
	JMS HCHECK	/CHECK VALIDITY
	DAC #HOUT
	JMS RDCHAR
	SAD (337)	/<-
	SKP
	JMP .+4
	LAC NSWOP+7	/JMP I NSWOP
	DAC NSWOP+1
	JMP .+10
	JMS NMREAD	/OUTPUT FILE NAME
	LAC NMBUFF
	DAC NMCOPY
	LAC NMBUFF+1
	DAC NMCOPY+1
	LAC NMBUFF+2
	DAC NMCOPY+2
	JMS RDDEV
	SAD (DT)
	SKP
	JMP H1
	JMS RDCHAR
	JMS HCHECK
	DAC #HIN
	DAC TRANO
	JMS RDCHAR
	SAD (254)	/,
	JMP I HINOUT
	SAD (240)
	JMP I HINOUT
	SAD (215)
	JMP I HINOUT
H1,	LAW ERR16
	TSR
	JMP BEGIN+3
/******
/******
HCHECK,	0	/CHECKS HANDLERS
	ADD (-260)
	DAC ACSAVE
	AND (-17)
	SZA
	JMP HCK1
	LAC ACSAVE
	JMP I HCHECK
HCK1,	LAW ERR1	/"ILLEGAL UNIT NUMBER"
	TSR
	JMS RDCHAR
	JMP HCHECK+1
/******
/******
VERIFY,	JMS RDCHAR
	DZM NMBUFF
	JMS HINOUT	/READ UNITS
	SAD (215)
	SKP
	JMP .+4
	LAC NSWOP+7
	DAC NSWOP+1
	SKP
	JMS NMREAD	/FILE NAME
	LAC HIN
	DAC NB-1
	JMS DBREAD
	JMS VCHECK
	JMP SFERR
	JMS STBGET	/FIND START BLOCK OF FILE
	DAC SCNT1	/SAVE START BLOCK
	LAC HOUT
	DAC NB-1
	DZM #DINSAV
	DZM #DOUTSAV
	JMS NSWOP
	JMS DBREAD
	JMS VCHECK
	JMP SFERR
	JMS STBGET
	DAC SCNT2
VERIF2,	DZM VHANER#
	KSF
	SKP
	JMS RDCHAR
	LAC HIN
	DAC NB-1
	LAC SCNT1
	DAC NB
	LAC DINSAV
	DAC DIRSAV
	JMS TREAD	/READ A "MASTER" BLOCK
	LAC (VHANLR)
	DAC NB+1	/USE VERIFY WORD HANDLER
	LAC DOUTSAV
	DAC DIRSAV
	LAC HOUT
	DAC NB-1
	LAC SCNT2
	DAC NB
	JMS TREAD	/COMPARE BLOCK
	LAW RHANLR
	DAC NB+1
	LAC FIOBUF+377
	SAD (-0)	/EOF?
	JMP BEGIN+3
	JMS DIRGET	/GET READ DIRECTION FOR MASTER FILE
	LAC FIOBUF+377
	ADD SCNT1
	DAC DINSAV
	LAC FIOBUF+377
	DAC SCNT1
	JMS DIRGET	/GET READ DIRECTION FOR FILE BEING CHECKED
	LAC VCHECK
	ADD SCNT2
	DAC DOUTSAV
	LAC VCHECK
	DAC SCNT2
	JMP VERIF2
/******
/******
DIRGET,	0	/ESTABLISHES READ DIRECTION
	XCT I DIRGET	/FIRST PARAMETER (DATA LINK)
	ISZ DIRGET
	CMA
	XCT I DIRGET	/2ND. PARAMETER (LAST BLOCK)
	SMA!CLA
	LAM -0
	ISZ DIRGET
	JMP I DIRGET
/******
/******
STBGET,	0	/GETS START BLOCK OF A FILE
	LAC SAVE	/FILE INDEX NUMBER
	JMS DENTRD	/EXAMINES DIRECTORY ENTRY
	LAC NMBUFF+3
	AND (1777)	/REMOVE FILE ACTIVE BIT
	JMP I STBGET
/******
/******
VHANLR,	0
	DAC STBGET
	LAC PTR
	SAD (FIOBUF+377)
	JMP V2	/END OF BLOCK
	LAC STBGET
	SAD I PTR
	SKP
	ISZ VHANER
	ISZ PTR
	JMP I VHANLR
V2,	LAC VHANER
	SNA
	JMP V1
	CLA
	MMLC	/STOP TRANSPORT
	LAW ERR17	/"VERIFY ERROR"
	TSR
	LAC SCNT2
	JMS OPS
	LAC NBLOCK+4
	SNA
	JMP .+3
	LAW 255
	JMS OTY
	LAW 327
	JMS OTY
	LAC SCNT1
	JMS OPS
	LAC NB+4
	SNA
	JMP .+3
	LAW 255
	JMS OTY
	LAW 322
	JMS OTY
	LAC STBGET
	DAC VCHECK
	JMP I TREAD
V1,	LAC STBGET
	DAC VCHECK
	JMP I VHANLR
/******
/******
QHANLR,	0
	DAC SCNT1
	LAC CNT
	ISZ CNT
	ADD (-3440)
	SMA
	JMP I QHANLR
	LAC SCNT1
	XOR SCNT
	DAC SCNT
	JMP I QHANLR
/******
/******
TCHECK,	0
	LAW QHANLR
	DAC NB+1
	LAC (10)
	DAC DBCNT
	DZM DIRSAV
	LAC (1)
	DAC CNT
	DZM SCNT
	LAC (71)
	DAC NB
	JMS TREAD
	LAC SCNT
	SAD (77600)
	JMP TCHEND
	SAD (477600)
	JMP TCHEND
	LAW ERR18	/"SYSTEMS BIT MAPS FUNNY"
	TSR
	LAC NB-1
	TAD (042460)	/DTX
	TY3
TCHEND,	LAW RHANLR
	DAC NB+1
	JMP I TCHECK
/******
/******
/THIS SECTION ARRANGES AUTOMATIC PROGRAM LOADING VIA FIRM
STEED,	JMS CPRINT
	LAC (2000)	/BIT 7
	DAC SWITCH#
	JMS RDCHAR
	SAD (215)	/CR - ASSUME UNIT 8
	SKP
	JMP .+3
	LAC (10)	/UNIT 8
	JMP FIRM
	JMS HANNO	/TRANSPORT FOR FIRM
	LAC NB-1
	JMP FIRM
PEDRO,	JMS CPRINT
	LAC (I)	/BIT 4
	JMP STEED+2
PLOTALOT,	JMS CPRINT
	LAC (200)	/BIT 10
	JMP STEED+2
PADDLE,	JMS CPRINT
	LAC (10000)	/BIT 5
	JMP STEED+2
RDF,	JMS CPRINT
	LAC (100)	/BIT 11
	JMP STEED+2
DSP,	JMS CPRINT
	LAC (400)	/BIT 9
	JMP STEED+2
COPCOM,	JMS CPRINT
	LAC (1000)	/BIT 8
	JMP STEED+2
STRIP,	JMS CPRINT
	LAC (4000)	/BIT 6
	JMP STEED+2
SADIE,	JMS CPRINT
	LAC (200000)	/BIT 1
	JMP STEED+2
DDT,	JMS CPRINT
	LAC (100000)	/BIT 2
	JMP STEED+2
/******
/******
CPRINT,	0
	AND (277)
	XOR (100)
	DAC TCHECK	/TEMPY SAVE
	LAW 336	/^
	JMS OTY
	LAC TCHECK
	JMS OTY
	JMP I CPRINT
/******
/******
FIRM,	ALSS+14	/FRIG ENTRY TO FIRM
	MMSE
	CLC!CLL
	LAW 60
	MMLC	MMEF	JMP .-1
	LAW 41	MMLC
	MMDF	SKP	JMP .+4
	MMEF	JMP .-4
	JMP .-7
	MMRD
	SAD (1)
	SKP
	JMP .-3
	LAW 42	MMLC
	LAC SWITCH
	JMP FSTART
FSTART=17627
/******
/******
/DEALS WITH INPUT OF FILES FROM PAPER TAPE
SADDFL,	JMS RDCHAR
	JMS HANNO
	LAW CPACK	/SELECT CHARACTER ROUTINE
	DAC #SGETCH	/SET UP SGETCH FOR JMS I INSTRUCTION
	LAC (LBUFF+42)
	DAC #LOVER	/TO DETECT LINE OVERFLOW
	JMS SFEST	/ESTABLISH FILE
	JMS PTATTN	/SEE IF READER READY
	JMS SLCOMP	/INPUT A LINE
	JMS SFADD	/ADD THE LINE TO THE FILE
	JMP .-2
/******
/******
/DEALS WITH OUTPUT OF FILES TO PAPER TAPE
SPUNCH,	JMS RDCHAR
	JMS HANNO	/DECTAPE UNIT NUMBER
	JMS SFIN	/READ IN FILE NAMES TO BE PUNCHED OR TYPED
	JMS SNGET	/FIND NAME OF NEXT FILE TO BE OPENED
	JMS SFOPEN	/OPEN FILE
	JMS SIBUFF	/SERVICES OUTPUT BUFFER
	JMP .-3	/GO FOR NEXT FILE
/******
/******
PTATTN,	0	/ROUTINE TO SEE IF READER LOADED
	LAM -5
	DAC 7	/SET CLOCK
	CLON	/SWITCH ON CLOCK
	RSA
	CLSF	/IS CLOCK FLAG SET
	SKP
	JMP .+6
	RSF	/IS READER FLAG SET
	JMP .-4	/WAIT IN LOOP FOR FIRST FLAG
	RRB	/HERE IF READER FLAG SET BEFORE CLOCK
	CLOF	/SWITCH OFF CLOCK
	JMP I PTATTN
	LAW ERR22	/"LOAD "
	TSR
	JMS NOUT
	TSP
	JMS RDCHAR
	SAD (222)	/CONTROL+R
	SKP
	JMP .-3
	JMS CPRINT
	JMP PTATTN+1
/******
/******
/FLEXO - ASCII CHARACTER CONVERSION ROUTINE
/OUTPUTS TO AN IOPS ASCII FILE
/ROUTINE TO READ IN AND CONVERT ONE CHARACTER
CHACHA,	0
	JMS SRTAPE
	SAD (7)	/UPPER CASE
	JMP CHUP
	SAD (26)	/LOWER CASE
	JMP CHDOWN
	DAC CANDV	/TEMPORARY SAVE
	LAW FLEXO	/START OF CHARACTER TABLE
	DAC PTAB#
	LAM -62	/LENGTH OF TABLE
	DAC CNT
CHMORE,	LAC CANDV
	SAD I PTAB
	JMP CHACON	/CHARACTER FOUND
	ISZ PTAB
	ISZ PTAB
	ISZ CNT
	JMP CHMORE
	JMP CHACHA+1	/NO CHARACTER
CHACON,	ISZ PTAB
	LAC CASE
	GSM
	LAC I PTAB
	SNL
	LRS+11
	AND (377)
	JMP I CHACHA
CHUP,	DZM CASE#
	JMP CHACHA+1
CHDOWN,	CLC	/-0
	DAC CASE#
	JMP CHACHA+1
/******
/******
/ATLAS FLEXO-WRITER TO IOPS ASCII CODE CONVERSION TABLE
FLEXO,
/FLEXO	ASCII (UC)	ASCII(LC)
	2	215215	/NEWLINE
	4	211211	/TAB
	20	240240	/SPACE
	121	301000	/A
	122	302000	/B
	103	303000	/C
	124	304000	/D
	105	305000	/E
	106	306000	/F
	127	307000	/G
	130	310000	/H
	111	311000	/I
	112	312000	/J
	133	313000	/K
	114	314000	/L
	135	315000	/M
	136	316000	/N
	117	317000	/O
	160	320000	/P
	141	321000	/Q
	142	322000	/R
	163	323000	/S
	144	324000	/T
	165	325000	/U
	166	326000	/V
	147	327000	/W
	150	330000	/X
	171	331000	/Y
	172	332000	/Z
	40	260247	/0, '
	61	261333	/1, (
	62	262335	/2, )
	43	263274
	64	264276
	45	265275
	46	266300
	67	267242
	70	270250
	51	271251
	37	257272
	54	244337
	52	241246
	73	334273
	57	256254
	75	253243
	76	255252
	177	0
	25	245245
	2	215215
	7	0
	26	0
	4	211211
	34	224224
	20	240240
/******
/******
START


