/DECTAPE INPUT: BYTE (PRE-PROCESSOR)
 .LOC 17000
    DISIZE
    .SIXBT 'DTB'
    200001                  /DT INPUT
    .SIXBT 'DTF'
DBI
    SPA!CLL!CLA; JMP DI8    /CLOSE ->
    JMP* USE                /EXIT FROM COROUTINE
DI1 JMS* DBI-1; DAC I       /GET WORD
    SNL!RAR; JMP DI8        /EOF ->
    RTR; RTR; RTR; RTR      /SHIFT RIGHT 9
    JMS USE                 /BYTE ONE
    LAC I
    JMS USE                 /BYTE TWO
    JMP DI1
DI8 LAC LDI1; DAC USE       /FOR RE-ENTRY
    CLL!CLC; JMS* DBI-1
    JMP* DBI
USE DI1
    STL; AND LI777
    JMP* DBI
LDI1 DI1
LI777 777
I
DISIZE=.

/DECTAPE OUTPUT: BYTE (POST-PROCESSOR)
 .LOC 17000
    .SIZE
    .SIXBT 'DTB'
    200002                  /DT OUTPUT
    .SIXBT 'DTF'
DBO
    SNL; JMP DO8            /CLOSE ->
    JMP* GET
DO1 JMS GET
DO2 RCL; RTL; RTL; RTL; RTL /SHIFT LEFT 9
    DAC J
    JMS GET
    TAD J; DZM J
    JMS* DBO-1
    SZL; JMP DO1
DO8 LAC J; SZA!STL; JMS* DBO-1
    DZM J
    LAC (DO2; DAC GET
    CLL!CLC; JMS* DBO-1
    JMP* DBO
GET DO2
    STL
    JMP* DBO
J
 .END
