1*TELESOFT
   10FOR Channel = 0 TO 3
   20   PRINT "Channel ";Channel+1;
   30   IF FNtransmitting(Channel) THEN PRINT " OK" ELSE PRINT " off air"
   40NEXT
   50END
   60 
   70 
   80DEFFNtransmitting(C%)
   90 
  100LOCAL I,regs
  110LOCAL Command_block
  120 
  130DIM Command_block 15
  140 
  160osword = &FFF1      :REM osword call address
  170 
  180A% = &7A   :REM Teletext osword number
  190X% = Command_block MOD 256
  200Y% = Command_block DIV 256
  210 
  220fetch_page = &85    :REM Teletext osword command codes
  230test_arrived = &89
  240select_channel = &8B
  250 
  260REM Select channel
  270 
  280   Command_block?0 = select_channel
  290   Command_block?1 = C%
  300   regs = USR(osword)
  310 
  320REM Ask for a completely wild-carded page
  330Command_block?0=&8A:regs=USR(osword)
  340 
  350   Command_block?0 = fetch_page
  360   FOR I = 1 TO 7
  370      Command_block?I = &FF   :REM Wild page digit is &FF
  380   NEXT I
  390   regs = USR(osword)
  400 
  410REM Now wait a bit for anything to arrive
  420 
  430   Timeout = 50
  440   Timeout = Timeout - 1
  450      *FX 19
  460      Command_block?0 = test_arrived
  470      regs = USR(osword)
  480   IF Command_block?1 = &FF THEN =TRUE
  490   IF Timeout > 0 THEN GOTO 440
  500=FALSE